extends BulletBase
class_name ParrierBullet

@export var parryRate: float = 1

var parryiedTimes: int = 0
var maxParryTimes: int = 1
var maxBallCount: int = 5
var atk: float = 1
var reflectRate: float = 1

func generateParryBall(bDamage: float):
	var cycler = launcher.getOrCreateCycleTimer("parry", 2000, 100)
	if len(cycler.bullets) < maxBallCount: # 玩家最多只能拥有多少气
		for b in BulletBase.generate(
			ComponentManager.getBullet("ParryBall"), # 生成气的子弹
			launcher,
			position,
			0
		):
			if b is ParryBallBullet:
				b.atk = atk * bDamage

func spawn():
	var varians = randi_range(0, 1)
	var inverts = [2]
	var frames = load("res://resources/effects/parrier/%d/%d.tres" % [varians, varians])
	var eff = EffectController.create(ComponentManager.getEffect("Parrier"), position)
	eff.rotation = rotation
	eff.texture.scale.y *= MathTool.randomChoiceFrom([-1, 1])
	if varians in inverts:
		eff.texture.scale.x *= -1
	eff.texture.sprite_frames = frames
	eff.shot()
func succeedToHit(_dmg: float, entity: EntityBase):
	if parryiedTimes < maxParryTimes && MathTool.rate(parryRate):
		ParryEntityEffect.createEffectEntity(entity, self )
func hitBullet(bullet: BulletBase): # 当前子弹与其他子弹相撞
	if !is_instance_valid(launcher): return
	if BulletTool.canDamage(bullet, launcher): # 其他子弹可以使当前子弹的发射者受伤吗？
		if parryiedTimes < maxParryTimes:
			if MathTool.rate(parryRate): # 一个刀光最多格挡多少个敌方子弹？
				# 可以格挡 挥舞运动（近战攻击）、射弹运动（远程攻击）和猛冲运动 的子弹，射弹如果被弹反则不会产生气力
				# 魔法运动和召唤运动的子弹虽不能格挡，但是可以储能，吐息运动的子弹会对发射者产生击退
				if bullet.motionType == BulletBase.MotionType.PROJECTILE:
					# 无论如何都要生成格挡特效
					ParryEffect.createEffect(bullet, self )
					# 弹反 还是 格挡？ 
					if MathTool.rate(reflectRate):
						bullet.look_at(bullet.launcher.getTrackingAnchor())
						bullet.launcher = launcher
						bullet.baseDamage = reflectRate * atk
						bullet.lifeTime *= 2
						if bullet.freeAfterSpawn && bullet.autoSpawnAnimation:
							bullet.animator.speed_scale *= 0.5
					else:
						bullet.tryDestroy()
						generateParryBall(bullet.baseDamage)
				elif bullet.motionType == BulletBase.MotionType.SWING:
					ParryEffect.createEffect(bullet, self )
					bullet.hitbox.set_deferred("disabled", true)
					generateParryBall(bullet.baseDamage)
					InternalDamageBullet.generateBall(launcher, bullet.launcher, atk)
				elif bullet.motionType == BulletBase.MotionType.STAB:
					ParryEffect.createEffect(bullet, self )
					ParryEntityEffect.createEffectEntity(bullet.launcher, self )
					bullet.hitbox.set_deferred("disabled", true)
					bullet.launcher.takeDamage(atk * reflectRate * bullet.getDamage())
					bullet.launcher.impluse(Vector2.from_angle(bullet.rotation) * -2000)
					generateParryBall(bullet.baseDamage)
					InternalDamageBullet.generateBall(launcher, bullet.launcher, atk)
				elif bullet.motionType == BulletBase.MotionType.SPRINT:
					ParryEffect.createEffect(bullet, self )
					bullet.tryDestroy()
					bullet.launcher.velocity *= 0
					generateParryBall(bullet.baseDamage)
					for i in 2:
						InternalDamageBullet.generateBall(launcher, bullet.launcher, atk)
				elif bullet.motionType == BulletBase.MotionType.BREATH:
					ParryEntityEffect.createEffectEntity(bullet.launcher, self )
					bullet.launcher.impluse(Vector2.from_angle(bullet.rotation) * -500)
				elif bullet.motionType == BulletBase.MotionType.SUMMON || bullet.motionType == BulletBase.MotionType.MAGIC:
					ParryEntityEffect.createEffectEntity(bullet.launcher, self )
					launcher.storeEnergy(sqrt(bullet.baseDamage))
				elif bullet.motionType == BulletBase.MotionType.EXPLOSION:
					ParryEntityEffect.createEffectEntity(bullet.launcher, self )
					for i in 2:
						InternalDamageBullet.generateBall(bullet.launcher, launcher, sqrt(bullet.getDamage()))
			else:
				InternalDamageBullet.generateBall(bullet.launcher, launcher, atk)

func refract(_newBullet: BulletBase, _entity: EntityBase, _index: int, _total: int, _lastBullet: float):
	return null
func split(_newBullet: BulletBase, _index: int, _total: int, _lastBullet: float):
	return null