Dog-Lynx-And-HCN/scripts/Contents/Bullets/Parrier.gd

extends BulletBase
class_name ParrierBullet

@export var parryRate: float = 1

var parryiedTimes: int = 0
var maxParryTimes: int = 1
var maxBallCount: int = 5
var atk: float = 1
var reflectRate: float = 1

func spawn():
	var varians = randi_range(0, 1)
	var inverts = [2]
	var frames = load("res://resources/effects/parrier/%d/%d.tres" % [varians, varians])
	var eff = EffectController.create(ComponentManager.getEffect("Parrier"), position)
	eff.rotation = rotation
	eff.texture.scale.y *= MathTool.randomChoiceFrom([-1, 1])
	if varians in inverts:
		eff.texture.scale.x *= -1
	eff.texture.sprite_frames = frames
	eff.shot()
func succeedToHit(_dmg: float, entity: EntityBase):
	if parryiedTimes < maxParryTimes && MathTool.rate(parryRate):
		parryiedTimes += 1
		var effSpawn = entity.texture.global_position
		var eff = EffectController.create(ComponentManager.getEffect("ParryEntity"), effSpawn)
		eff.rotation = position.angle_to_point(effSpawn)
		eff.shot()
		entity.impluse((effSpawn - position).normalized() * 450)
func hitBullet(bullet: BulletBase): # 当前子弹与其他子弹相撞
	if !is_instance_valid(launcher): return
	if BulletTool.canDamage(bullet, launcher): # 其他子弹可以使当前子弹的发射者受伤吗？
		if parryiedTimes < maxParryTimes && MathTool.rate(parryRate): # 一个刀光最多格挡多少个敌方子弹？
			parryiedTimes += 1
			# 生成格挡特效
			var eff = EffectController.create(ComponentManager.getEffect("Parry"), position + (bullet.position - position).normalized() * 200) # 从子弹位置，面向其他子弹的方向前进150
			eff.modulate = bullet.modulate.blend(bullet.texture.modulate)
			eff.rotation = position.angle_to_point(bullet.position)
			eff.shot()
			launcher.impluse((position - bullet.position).normalized() * bullet.speed ** (1.0 / 2) * 250)
			var targetBaseDamage = bullet.baseDamage
			if bullet.motionType == BulletBase.MotionType.PROJECTILE:
				# 弹反 还是 格挡？
				if MathTool.rate(reflectRate):
					bullet.look_at(bullet.launcher.getTrackingAnchor())
					bullet.launcher = launcher
					bullet.baseDamage *= atk
					bullet.baseDamage *= reflectRate
					bullet.lifeTime *= 2
					if bullet.freeAfterSpawn && bullet.autoSpawnAnimation:
						bullet.animator.speed_scale *= 0.5
				else:
					bullet.tryDestroy()
			elif bullet.motionType == BulletBase.MotionType.SWING:
				bullet.hitbox.disabled = true
			elif bullet.motionType == BulletBase.MotionType.SPRINT:
				bullet.tryDestroy()
				bullet.launcher.velocity *= -0.1
			elif bullet.motionType == BulletBase.MotionType.SUMMON || bullet.motionType == BulletBase.MotionType.MAGIC:
				launcher.storeEnergy(sqrt(bullet.baseDamage))
			var cycler = launcher.getOrCreateCycleTimer("parry", 2000, 100)
			if len(cycler.bullets) < maxBallCount: # 玩家最多只能拥有多少气
				for b in BulletBase.generate(
					ComponentManager.getBullet("ParryBall"), # 生成气的子弹
					launcher,
					position,
					0
				):
					if b is ParryBallBullet:
						b.atk = atk * targetBaseDamage
func refract(_newBullet: BulletBase, _entity: EntityBase, _index: int, _total: int, _lastBullet: float):
	return null
func split(_newBullet: BulletBase, _index: int, _total: int, _lastBullet: float):
	return null