Dog-Lynx-And-HCN/scripts/Contents/Bullets/Parrier.gd

extends BulletBase
class_name ParrierBullet

@export var parryRate: float = 1

var parryiedTimes: int = 0
var maxParryTimes: int = 1
var maxBallCount: int = 5
var atk: float = 1
var reflectRate: float = 1

func parryEffect(bullet: BulletBase):
	parryiedTimes += 1
	var eff = EffectController.create(ComponentManager.getEffect("Parry"), position + (bullet.position - position).normalized() * 200) # 从子弹位置，面向其他子弹的方向前进150
	eff.modulate = bullet.modulate.blend(bullet.texture.modulate)
	eff.rotation = position.angle_to_point(bullet.position)
	eff.shot()
	launcher.impluse((position - bullet.position).normalized() * sqrt(abs(bullet.speed)) * 250)
func penerateEffect(entity: EntityBase, effPos: Vector2):
	parryiedTimes += 1
	var eff = EffectController.create(ComponentManager.getEffect("ParryEntity"), effPos)
	eff.rotation = entity.position.angle_to_point(effPos)
	eff.shot()
	entity.impluse((entity.position - effPos).normalized() * 450)
func generateParryBall(bDamage: float):
	var cycler = launcher.getOrCreateCycleTimer("parry", 2000, 100)
	if len(cycler.bullets) < maxBallCount: # 玩家最多只能拥有多少气
		for b in BulletBase.generate(
			ComponentManager.getBullet("ParryBall"), # 生成气的子弹
			launcher,
			position,
			0
		):
			if b is ParryBallBullet:
				b.atk = atk * bDamage

func spawn():
	var varians = randi_range(0, 1)
	var inverts = [2]
	var frames = load("res://resources/effects/parrier/%d/%d.tres" % [varians, varians])
	var eff = EffectController.create(ComponentManager.getEffect("Parrier"), position)
	eff.rotation = rotation
	eff.texture.scale.y *= MathTool.randomChoiceFrom([-1, 1])
	if varians in inverts:
		eff.texture.scale.x *= -1
	eff.texture.sprite_frames = frames
	eff.shot()
func succeedToHit(_dmg: float, entity: EntityBase):
	if parryiedTimes < maxParryTimes && MathTool.rate(parryRate):
		penerateEffect(entity, entity.position * 1.01)
func hitBullet(bullet: BulletBase): # 当前子弹与其他子弹相撞
	if !is_instance_valid(launcher): return
	if BulletTool.canDamage(bullet, launcher): # 其他子弹可以使当前子弹的发射者受伤吗？
		if parryiedTimes < maxParryTimes && MathTool.rate(parryRate): # 一个刀光最多格挡多少个敌方子弹？
			# 可以格挡 挥舞运动（近战攻击）、射弹运动（远程攻击）和猛冲运动 的子弹，射弹如果被弹反则不会产生气力
			# 魔法运动和召唤运动的子弹虽不能格挡，但是可以储能，吐息运动的子弹会对发射者产生击退
			if bullet.motionType == BulletBase.MotionType.PROJECTILE:
				# 无论如何都要生成格挡特效
				parryEffect(bullet)
				# 弹反 还是 格挡？
				if MathTool.rate(reflectRate):
					bullet.look_at(bullet.launcher.getTrackingAnchor())
					bullet.launcher = launcher
					bullet.baseDamage = reflectRate * atk
					bullet.lifeTime *= 2
					if bullet.freeAfterSpawn && bullet.autoSpawnAnimation:
						bullet.animator.speed_scale *= 0.5
				else:
					bullet.tryDestroy()
					generateParryBall(bullet.baseDamage)
			elif bullet.motionType == BulletBase.MotionType.SWING:
				parryEffect(bullet)
				bullet.hitbox.set_deferred("disabled", true)
				generateParryBall(bullet.baseDamage)
			elif bullet.motionType == BulletBase.MotionType.STAB:
				parryEffect(bullet)
				penerateEffect(bullet.launcher, bullet.launcher.position * 1.01)
				bullet.hitbox.set_deferred("disabled", true)
				bullet.launcher.takeDamage(atk * reflectRate * bullet.getDamage())
				bullet.launcher.impluse(Vector2.from_angle(bullet.rotation) * -2000)
				generateParryBall(bullet.baseDamage)
			elif bullet.motionType == BulletBase.MotionType.SPRINT:
				parryEffect(bullet)
				bullet.tryDestroy()
				bullet.launcher.velocity *= -0.1
				generateParryBall(bullet.baseDamage)
			elif bullet.motionType == BulletBase.MotionType.BREATH:
				penerateEffect(bullet.launcher, launcher.position)
				bullet.launcher.impluse(Vector2.from_angle(bullet.rotation) * -500)
			elif bullet.motionType == BulletBase.MotionType.SUMMON || bullet.motionType == BulletBase.MotionType.MAGIC:
				penerateEffect(bullet.launcher, launcher.position)
				launcher.storeEnergy(sqrt(bullet.baseDamage))

func refract(_newBullet: BulletBase, _entity: EntityBase, _index: int, _total: int, _lastBullet: float):
	return null
func split(_newBullet: BulletBase, _index: int, _total: int, _lastBullet: float):
	return null